大家好，今天我们系统讲解 WPS 里所有的求和函数。从最基础的 SUM，到条件求和 SUMIF、SUMIFS，再到分类汇总 SUBTOTAL、高级乘积求和 SUMPRODUCT，最后讲跨表 3D 求和与常见错误。学完之后，工作中 99% 的求和问题你都能一招解决。

一、基础求和篇 · SUM

为什么 90% 的求和错误，都源于没有真正理解 SUM？

语法结构：=SUM(数值1,[数值2]……)。

示例：

目的：计算基本工资总和及每个人的实发工资。

操作要点：

在目标单元格中输入公式：=SUM(B2:B5)、=SUM(B2:D2)。

二、SUM 三大实战技巧：90% 的人只会第一招

技巧一： Alt+= 一键求和

操作要点：

① 选中数据区域下方或右侧的空单元格。

② 按下 Alt + =。

③ 自动生成 SUM 公式，回车确认。

适用场景：行列同时求和、快速做合计行。

专家提醒：这是 WPS 与 Excel 通用的最快求和法，每天能省下大量拖拽时间。

技巧二：不连续多区域求和

操作要点：=SUM(B2:B5, D2:D5)。

要点解读：逗号 = 并集，把基本工资列和补贴列一起求和。

常见错误：用空格代替逗号，WPS 会把它当「区域交集」运算符，得到完全不同的结果。

技巧三：区域含错误值

操作要点：=AGGREGATE(9, 6, B2:B5)（第 2 参数 6 = 忽略错误值）。

痛点：区域里只要有一个 #N/A、#DIV/0!，普通 SUM 直接返回错误。

三、条件求和篇 · SUMIF / SUMIFS

为什么领导一句「只要市场部的数据」，你要算半小时？

（一）SUMIF：单条件求和

语法结构：=SUMIF(条件区域, 条件, [求和区域])。

第 3 参数省略时，直接对第 1 参数本身求和。

示例：

目的：求「市场部」工资总额。

操作要点：在目标单元格中输入公式：=SUMIF(B2:B7,"市场部",C2:C7)。

易错点：条件区域与求和区域行数必须一致，否则结果错位。

（二）SUMIF+通配符：模糊匹配求和

三个通配符：

目的：计算“华东”所有地区和产品包含“无线”的销售额。

操作要点：在目标单元格中分别输入：=SUMIF(大区列, "华东*", 销售额列)、=SUMIF(商品列, "*无线*", 销售额列)。

（三）SUMIFS：多条件求和

语法结构：=SUMIFS(求和区域, 条件区域1, 条件1, …)。

关键记忆点：求和区域在第一位！与 SUMIF 正好相反。

示例：

目的：计算“华东”区“电子产品”的销售额。

操作要点：

在目标单元格中输入公式：=SUMIFS(D2:D8,B2:B8,"华东",C2:C8,"电子产品")。

要点解读：

1.两个条件之间是AND关系，必须同时成立。

2.最多支持 127 对条件，办公场景足够。

（四）SUMIFS 日期区间：求「本月」「最近 30 天」销售额

核心写法：用 & 连接比较符与日期。

=SUMIFS(销售额列, 日期列,">="&开始日期, 日期列, "<="&结束日期)

要点：比较符在双引号里，日期用 & 连接，不要写在同一对引号里。

示例：

目的：计算2月份的销售总额。

操作要点：在目标单元格中输入公式：=SUMIFS(B2:B6,A2:A6,">="&DATE(2024,2,1),A2:A6,"<="&DATE(2024,2,29))。

更灵活的写法：开始、结束日期放在两个单元格里引用，改日期公式自动重算。

四、DSUM：数据库求和，条件写在表里，不写在公式里

语法结构：=DSUM(数据库区域, 字段, 条件区域)。

条件区域 = 表头行 + 条件行，整张条件单独写在单元格里。

目的：求“销售部”工资总额。

操作要点：

在目标单元格中输入公式：=DSUM(A1:C8,"工资",E1:E2)。

要点解读：

字段写法：可写字段名"工资"，也可以写列号 3。

条件区域：表头必须和数据库完全一致。

专家对比：DSUM 与 SUMIFS 结果相同，但条件写在单元格里，改条件不用动公式，适合条件经常变动的报表。

五、分类汇总篇 · SUBTOTAL

为什么你筛选之后，求和结果还把隐藏行算进去了？

语法结构：=SUBTOTAL(功能代码,数据区域)。

功能代码：

最容易混淆的 9 与 109：

1.代码9 = 求和：忽略筛选隐藏的行，但包含手动隐藏的行。

2.编号 109 = 求和：同时忽略筛选和手动隐藏的行。

专家建议：做数据看板时统一用 109，行为最符合直觉。

案例：同一列数据，筛选后 SUM 与 SUBTOTAL 结果差一倍

操作要点：

1.在目标单元格中分别输入：=SUM(C2:C6)、=SUBTOTAL(109, C2:C6)。

2.在没有筛选前结果都为40000，但在筛选“华东”地区后，SUMTOTOAL的结果更新为22000（5000+8000+9000），只计算了3个可见行。

六、高级应用篇 · SUMPRODUCT / 3D

为什么高手从不加辅助列？因为他们会用 SUMPRODUCT。

语法结构：=SUMPRODUCT(数组1,[数组2]……)。

原理：对应位置相乘，再把所有乘积加起来。

示例（一）：两列对应相乘再求和，不用辅助列

目的：计算总销售额。

操作要点：

在目标单元格中输入公式：=SUMPRODUCT(B2:B5,C2:C5)。

要点解读：2180= 5×100 + 3×200 + 6×80 + 12×50；对应位置的元素相乘之后求和（先乘再求和）。

铁律：所有数组的行列数必须完全一致，否则返回 #VALUE!。

示例（二）：SUMPRODUCT 进阶：加权总分与多条件双杀

用法一：按权重算学生综合成绩

示例：

操作要点：

在目标单元格中输入公式：=SUMPRODUCT(B2:D2,$B$3:$D$3)。

要点解读：

1.89.5= 90×20% + 85×30% + 92×50% = 89.5。

2.权重行要绝对引用，以便填充其它同学的加权总分。

用法二：多条件求和（替代 SUMIFS）

示例：

目的：计算“华东”地区“电子产品”的总销售额。

操作要点：

在目标单元格中输入公式：=SUMPRODUCT((B2:B8="华东")*(C2:C8="电子产品"),D2:D8)。

要点解读：条件成立为 1、不成立为 0，相乘后只保留双 1 的行。

SUMPRODUCT的铁律：

① 所有数组维度必须完全一致。

② 数组里出现文本、空白会被当 0。

③ 数据量大（万行以上）时比 SUMIFS 慢，优先用 SUMIFS。

④ WPS 新版直接回车即可，不需要数组三键。

七、3D 引用：一张表汇总 12 个月工作表，只需一条公式

语法要点：=SUM('起始表:结束表'!单元格)。

冒号连接首尾表名，一次性引用连续的多个工作表。

案例：计算全年的销售额。

操作要点：每个月一张表，B2 是当月总销售额；在汇总单元格中输入公式：=SUM('1月:12月'!B2)。

好处：中间插入新表、删除旧表，引用自动包含。

使用 3D 引用的三个前提：

① 被引用的工作表必须连续排列。

② 表名含空格或中文时，单引号不能省。

③ 所有表里对应单元格位置必须一致。

常见错误：表名没加单引号、表顺序不连续，结果会漏算或报错。

八、避坑指南